selinux-policy/refpolicy/policy/modules/system/mount.if

## <module name="mount">
## <summary>Policy for mount.</summary>

########################################
## <interface name="mount_domtrans">
##	<desc>
##		Execute mount in the mount domain.
##	</desc>
##	<param name="domain">
##		The type of the process performing this action.
##	</param>
## </interface>
#
interface(`mount_domtrans',`
	gen_require(`
		type mount_t, mount_exec_t;
		class process sigchld;
		class fd use;
		class fifo_file rw_file_perms;
	')

	domain_auto_trans($1,mount_exec_t,mount_t)

	allow $1 mount_t:fd use;
	allow mount_t $1:fd use;
	allow mount_t $1:fifo_file rw_file_perms;
	allow mount_t $1:process sigchld;
')

########################################
## <interface name="mount_run">
##	<desc>
##		Execute mount in the mount domain, and
##		allow the specified role the mount domain,
##		and use the caller's terminal.
##	</desc>
##	<param name="domain">
##		The type of the process performing this action.
##	</param>
##	<param name="role">
##		The role to be allowed the mount domain.
##	</param>
##	<param name="terminal">
##		The type of the terminal allow the mount domain to use.
##	</param>
## </interface>
#
interface(`mount_run',`
	gen_require(`
		type mount_t;
		class chr_file rw_file_perms;
	')

	mount_domtrans($1)
	role $2 types mount_t;
	allow mount_t $3:chr_file rw_file_perms;
')

########################################
## <interface name="mount_use_fd">
##     <desc>
##             Use file descriptors for mount.
##     </desc>
##     <param name="domain">
##             The type of the process performing this action.
##     </param>
## </interface>
#
interface(`mount_use_fd',`
	gen_require(`
		type mount_t;
		class fd use;
	')

	allow $1 mount_t:fd use; 
')

########################################
## <interface name="mount_send_nfs_client_request">
##     <desc>
##             Allow the mount domain to send nfs requests for mounting
##             network drives
##     </desc>
##     <param name="domain">
##             The type of the process performing this action.
##     </param>
## </interface>
#
interface(`mount_send_nfs_client_request',`
	gen_require(`
		type mount_t;
		class udp_socket rw_socket_perms;
	')

	allow $1 mount_t:udp_socket rw_socket_perms;
')

## </module>