selinux-policy/policy/modules/services/clockspeed.if

## <summary>Clockspeed simple network time protocol client</summary>

########################################
## <summary>
##      Execute clockspeed utilities in the clockspeed_cli domain.
## </summary>
## <param name="domain">
##      <summary>
##      Domain allowed access.
##      </summary>
## </param>
#
interface(`clockspeed_domtrans_cli',`
        gen_require(`
                type clockspeed_cli_t, clockspeed_cli_exec_t;
        ')

	domtrans_pattern($1, clockspeed_cli_exec_t, clockspeed_cli_t)
')

########################################
## <summary>
##	Allow the specified role the clockspeed_cli domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	The role to be allowed the clockspeed_cli domain.
##	</summary>
## </param>
## <param name="terminal">
##	<summary>
##	The type of the terminal allow the clockspeed_cli domain to use.
##	</summary>
## </param>
## <rolecap/>
#
template(`clockspeed_run_cli',`
	gen_require(`
		type clockspeed_cli_t;
	')

	role $2 types clockspeed_cli_t;
	clockspeed_domtrans_cli($1)
	allow clockspeed_cli_t $3:chr_file { getattr read write ioctl };

')