selinux-policy/refpolicy/policy/modules/admin/dmidecode.if

## <summary>Decode DMI data for x86/ia64 bioses.</summary>

########################################
## <summary>
##	Execute dmidecode in the dmidecode domain.
## </summary>
## <param name="domain">
##	<summary>
##	Domain allowed access.
##	</summary>
## </param>
#
interface(`dmidecode_domtrans',`
	gen_require(`
		type dmidecode_t, dmidecode_exec_t;
	')

	domain_auto_trans($1,dmidecode_exec_t,dmidecode_t)

	allow $1 dmidecode_t:fd use;
	allow dmidecode_t $1:fd use;
	allow dmidecode_t $1:fifo_file rw_file_perms;
	allow dmidecode_t $1:process sigchld;
')

########################################
## <summary>
##	Execute dmidecode in the dmidecode domain, and
##	allow the specified role the dmidecode domain.
## </summary>
## <param name="domain">
##	<summary>
##	The type of the process performing this action.
##	</summary>
## </param>
## <param name="role">
##	<summary>
##	The role to be allowed the dmidecode domain.
##	</summary>
## </param>
## <param name="terminal">
##	<summary>
##	The type of the terminal allow the dmidecode domain to use.
##	</summary>
## </param>
#
interface(`dmidecode_run',`
	gen_require(`
		type dmidecode_t;
	')

	dmidecode_domtrans($1)
	role $2 types dmidecode_t;
	allow dmidecode_t $3:chr_file rw_term_perms;
')